excel相隔两列如何求和（excel竖列自动求和公式）

我是【桃大喵学习记】，欢迎大家关注哟~，每天为你分享职场办公软件使用技巧干货！

日常工作中，我们经常需要对Excel表格数据进行求和计算，今天就跟大家分享一下对Excel表格隔列求和的3种方法，你看看更喜欢哪一种解决方法？

如下图所示，这是每个员工1-3月份实际销售额和目标销售统计表，我们需要计算每个员工1-3月份实际销售额。

excel相隔两列如何求和,excel竖列自动求和公式(1)

方法一：使用SUMIF函数根据条件隔列求和

在目标单元格中输入公式：

=SUMIF($B$2:$G$2,$B$2,B3:G3)

然后点击回车，下拉填充数据即可。

excel相隔两列如何求和,excel竖列自动求和公式(2)

解读：

①主要是利用了SUMIF函数条件求和。
第1参数：条件区域就是$B$2:$G$2，这些单元格中的值包含“实际”和“目标”，需要锁行锁列所以，选择数据区域后按一次F4键；
第2参数：条件就是$B$2也就是单元格中“实际”；
第3参数：求和区域B3:G3；
总之，公式就是将B2:G2数据区域中单元格中值是“实际”的单元格所对应的实际求和区域B3:G3进行求和计算。
②SUMIF函数简介
功能：SUMIF函数是一个单条件求和函数。
语法：=SUMIF(条件区域，条件，求和区域)

方法二：使用SUMPRODUCT单条件求和

在目标单元格格中输入公式：

=SUMPRODUCT(($B$2:$G$2=$B$2)*$B3:$G3)

然后点击回车，下拉填充数据即可。

excel相隔两列如何求和,excel竖列自动求和公式(3)

解读：

①其实，实现上面跨列汇总求和，主要就是使用了SUMPRODUCT函数条件求和。
②公式中的($B$2:$G$2=$B$2)就是把B2:G2数据区域单元格中的值“实际”和“目标”这行数据的每个元素跟B2单元格个中的“实际”称做判断，返回的结果是一个数组由逻辑值TRUE或者FALSE（备注：逻辑值TRUE可以看做1，逻辑值FALSE可以看做0）组成。下拉填充数据时这个判断条件不变，所以需要绝对引用，锁行锁列，就是选择数据后按一次F4键。
③最后再跟$B3:$G3数据区域先乘积，再求和，因为需要向下填充数据，所以锁列不锁行，就是选择数据后按三次F4键。
④SUMPRODUCT函数介绍
函数功能：SUMPRODUCT函数主要功能是返回相应的数据或区域乘积的和。
语法结构：=SUMPRODUCT（数组1,数组2,数组3, ...）。

方法三、使用SUMPRODUCT、MOD、COLUMN三个函数隔列求和

在目标单元格中输入公式：

=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)

然后点击回车，下拉填充数据即可。

excel相隔两列如何求和,excel竖列自动求和公式(4)

解读：

1、公式解读
①首先公式中COLUMN(B3:G3)返回数据区域单元格的列数，返回{2,3,4,5,6,7}；
②然后MOD(COLUMN(B3:G3),2)返回的结果为{0,1,0,1,0,1};
③(MOD(COLUMN(B3:G3),2)=0)再判断等于0后返回一组由逻辑值TRUE或者FALSE（备注：逻辑值TRUE可以看做1，逻辑值FALSE可以看做0）组成；
④最后在与数据区域B3:G3相乘即可。
2、用这个组合可以解决所有有规律隔行求和场景
每隔1列求和：
=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)
每隔2列求和：
=SUMPRODUCT((MOD(COLUMN(B3:G3),3)=0)*B3:G3)
每隔3列求和：
=SUMPRODUCT((MOD(COLUMN(B3:G3),4)=0)*B3:G3)
万能公式：每隔n列求和
=SUMPRODUCT((MOD(COLUMN(B3:G3),n 1)=0)*B3:G3)
其中，B3:G3就是求和区域，n 1中的n就是要隔几列求和。